In-vitro Homogenate ETC Biochemical Network Model

Ivan Chang

State variables, parameters, and constants

State variables

var={
Hi,
He,
NADH, (*  NADH concentration in the Matrix *)
NAD,
CoQH2, (* CoQH2 concentration in the Matrix *)
CoQ,
cytCred, (* cytochrome (reduced form) concentration in the Intermembrane space *)
cytCox,
O2 (* Oxygen concentration in the external space *)
};

Constants

T=300;(*Kelvin*)
R=8.31;(*(J/(K mol))*)
F=96.485;(*(C/(1000 mol))*)
S=2.303R T;
Z = 2.303 (((R T))/F);
u = 0.861;
Rcm=15;
Bn=5;
NADtot=100; (*NADtot=NADH+NAD*)
CoQtot=100; (*CoQtot=CoQ+CoQH2*)
cytCtot=50; (*cytCtot=cytCred+cytCox*)
H20=1;
TOL=0.0001;
(* Default values
  NADtot=300;
	CoQtot=150;
	cytCtot=30;
*)

Adjustable Parameters

adjust={
VmaxDH->280,
KrDH->100,
pD->0.8,
VmaxC1->110,
KrDC1->0.03,
KrAC1->0.3,
γC1->1,
VmaxC3->360,
KrDC3->0.54,
KrAC3->2.26,
γC3->1,
VmaxC4->235,
KrDC4->3.56,
KrAC4->0.1,
γC4->1,
KsDC1->15.062525929789151`,
KsAC1->22.524554276885997`,
KsDC3->154,
KsAC3->8,
KsDC4->5.1492859866681995`
};

Calculated variables

pH & Proton Motive Force (ΔP)

pHe[t_]:=-Log[10,((He[t])/1000000)];
pHi[t_]:=-Log[10,((Hi[t])/1000000)];
ΔpH[t_]:=Z(pHi[t]-pHe[t]);
ΔP[t_]:=(1/(1-u))ΔpH[t];

Membrane Potential & Buffer

ΔΨ[t_]:=-(ΔP[t]-ΔpH[t])
Ψi[t_]:=0.65ΔΨ[t];
Ψe[t_]:=-0.35ΔΨ[t];

Thermodynamic values

nA=2.5;
ΔEoC1 = 359.49; (* Standard Electrical Potential in C1,mV *)
ΔEoC3 = 168.58; (* Standard Electrical Potential in C3,mV *)
ΔEoC4 = 318.55; (* Standard Electrical Potential in C4,mV *)

Dynamic Equations

Accessory Processes

Dehydrogenase

(*JDH[t_]:=kDH (1/(((1+(KmN/(NAD[t]/NADH[t]))))^pD));original Korzeniewski JDH equation*)
NADratio[t_]:=((NAD[t])/(NADH[t]));
JDH[t_]:=VmaxDH(((((NADratio[t])/(NADratio[t]+KrDH))))^pD);(*Converted JDH*)

Proton Motive Force

ΔGH[t_]:=F ΔΨ[t]-ΔpH[t];

Electron Transport Chain Complexes

Complex I

NADHratio[t_]:=((NADH[t])/(NAD[t]));
CoQratio[t_]:=((CoQ[t])/( CoQH2[t]));
RdC1[t_]:=(((NADHratio[t])/(NADHratio[t]+KrDC1 )));
RaC1[t_]:=(((CoQratio[t])/(CoQratio[t]+KrAC1 )));
RC1[t_]:=RdC1[t]RaC1[t]
(*ΔXC1[t_]:=2 F ΔEoC1 + R T Log[((1/(KrDC1 KrAC1)))((NADH[t] CoQ[t])/(NAD[t] CoQH2[t]))]-4ΔGH[t]; with pmf*)
ΔXC1[t_]:=2 F ΔEoC1 + R T Log[NADHratio[t]CoQratio[t]];
TC1[t_]:=(1-Exp[((-γC1 ΔXC1[t])/(R T))]);
SC1[t_]:=((NADtot/(NADtot+KsDC1)))((CoQtot/(CoQtot+KsAC1)));
JC1[t_]:=VmaxC1 SC1[t]RC1[t] TC1[t];

Complex III

CoQH2ratio[t_]:=((CoQH2[t])/(CoQ[t]));
cytCoxratio[t_]:=((cytCox[t])/(cytCred[t]));
RdC3[t_]:=(((CoQH2ratio[t])/(CoQH2ratio[t]+KrDC3 )));
RaC3[t_]:=(((cytCoxratio[t])/(cytCoxratio[t]+KrAC3 )));
RC3[t_]:=RdC3[t] RaC3[t];
(*ΔXC3[t_]:=2 F ΔEoC3 + 2R T Log[((Hi[t])/(10^(-7.2)))]+R T Log[((1/KrDC3))((CoQH2[t])/(CoQ[t]))]+ 2 R T Log[((1/KrAC3))((cytCox[t])/(cytCred[t]))]-4ΔGH[t]+2F ΔΨ[t];*)
ΔXC3[t_]:=2 F ΔEoC3 +R T Log[CoQH2ratio[t]]+ 2 R T Log[cytCoxratio[t]];
TC3[t_]:=(1-Exp[((-γC3 ΔXC3[t])/(2R T))]);
SC3[t_]:=((CoQtot/(CoQtot+KsDC3)))((cytCtot/(cytCtot+KsAC3)));
JC3[t_]:=VmaxC3 SC3[t]RC3[t] TC3[t];

Complex IV

cytCredratio[t_]:=((cytCred[t])/(cytCox[t]));
O2ratio[t_]:=((O2[t])/H20);
RdC4[t_]:=(((cytCredratio[t])/(cytCredratio[t]+KrDC4 )));
RaC4[t_]:=(((O2ratio[t])/(O2ratio[t]+KrAC4)));
RC4[t_]:=RdC4[t]  RaC4[t];
(*ΔXC4[t_]:=4 F ΔEoC4 + 2R T Log[((Hi[t])/(10^(-7.2)))]+((R T)/2) Log[((O2ratio[t])/KrAC4)]+2 R T Log[((cytCredratio[t])/KrDC4)]-2ΔGH[t]-2F ΔΨ[t];*)
ΔXC4[t_]:=4 F ΔEoC4 + ((R T)/2) Log[O2ratio[t]]+2 R T Log[cytCredratio[t]];
TC4[t_]:=(1-Exp[((-γC4 ΔXC4[t])/(2R T))]);
SC4[t_]:=((cytCtot/(cytCtot+KsDC3)));
JC4[t_]:=VmaxC4 SC4[t]RC4[t]TC4[t];

Governing Equations

myODE = {
NADH'[t] ==JDH[t] - JC1[t],
CoQH2'[t]==JC1[t]-JC3[t],
cytCred'[t]==2JC3[t]-2 JC4[t],
O2'[t]==0,(*Open system*)
Hi'[t]==0,(*broken membrane*)
He'[t]==0 (*broken membrane*)
  };

balance = {
NAD[t]+NADH[t]==NADtot,
CoQ[t]+CoQH2[t]== CoQtot,
cytCred[t]+cytCox[t]==cytCtot
};
NADHNormal[t_] :=((NADH[t])/NADtot);
CoQNormal[t_]:=((CoQH2[t])/CoQtot);
cytCredNormal[t_] :=((cytCred[t])/cytCtot);

Initial Conditions

InitialConditions = {
NADH[0]==NADtot-TOL,
NAD[0]==TOL,
CoQH2[0]==CoQtot-TOL,
CoQ[0]==TOL,
cytCred[0]==cytCtot-TOL,
cytCox[0]==TOL,
O2[0]==30,
Hi[0]==(10^(-7.2))*1000000,
He[0]==(10^(-7.2))*1000000
};

Simulation

Simulation parameters

endTime=200;
TOL=0.0001;
CIColor=CMYKColor[0.0392,0.0863,0.949,0];
CIIIColor=CMYKColor[0.1922,0.8392,0.6039,.0471];
CIVColor=CMYKColor[0.7804,0.1843,1,0.0392];

Simulation result - Timeseries

sol=NDSolve[Join[myODE/.adjust,D[balance,t],InitialConditions], var, {t, 0, endTime}];

Redox Ratios at Steady State

NADH[endTime]/.sol
NAD[endTime]/.sol
NADHratio[endTime]/.sol
NADratio[endTime]/.sol
CoQH2[endTime]/.sol
CoQ[endTime]/.sol
CoQ[endTime]/CoQH2[endTime]/.sol
CoQH2ratio[endTime]/.sol
CoQratio[endTime]/.sol
cytCox[endTime]/.sol
cytCred[endTime]/.sol
cytCoxratio[endTime]/.sol
cytCredratio[endTime]/.sol

Steady State Flux

JC4[endTime]/.adjust/.sol

Steady State Concentrations

NADHss =(NADH[endTime]/.sol)[[1]]
NADss = (NAD[endTime]/.sol)[[1]]
CoQss = (CoQ[endTime]/.sol)[[1]]
CoQH2ss = (CoQH2[endTime]/.sol)[[1]]
cytCoxss = (cytCox[endTime]/.sol)[[1]]
cytCredss = (cytCred[endTime]/.sol)[[1]]
Steadystate={
NADH[0]==NADHss,
NAD[0]==NADss,
CoQH2[0]==CoQH2ss,
CoQ[0]==CoQss,
cytCred[0]==cytCredss,
cytCox[0]==cytCoxss,
O2[0]==30,
Hi[0]==(10^(-7.2))*1000000,
He[0]==(10^(-7.2))*1000000
};

Parameter Variation and Threshold

Needs["PlotLegends`"]

Global Flux Parameter Variation

Adjustment Functions

adjustSteadystate[i_]:=ReplacePart[Steadystate, {3->CoQH2[0]== CoQtot (1-10*i),4->CoQ[0]==(1-CoQtot(1-10*i))}];
adjustC1Vmax[i_]:=ReplacePart[adjust, {4->VmaxC1->adjust[[4,2]](1-((i/100)))}];
adjustC3Vmax[i_]:=ReplacePart[adjust, {8->VmaxC3->adjust[[8,2]](1-((i/100)))}];
adjustC4Vmax[i_]:=ReplacePart[adjust, {12->VmaxC4->adjust[[12,2]](1-((i/100)))}];
adjustC1Kmd[i_]:=ReplacePart[adjust, {16->KmDC1->adjust[[16,2]](1-((i/100)))}];
adjustC1Kma[i_]:=ReplacePart[adjust, {17->KmAC1->adjust[[17,2]](1-((i/100)))}];

Timeseries generation

Complex I

Do[solC1Vmax[i]=NDSolve[Join[myODE/.adjustC1Vmax[i],D[balance,t],Steadystate],var,{t,0,endTime}], {i,0,100}];
Do[solC1Kmd[i]=NDSolve[Join[myODE/.adjustC1Kmd[i],D[balance,t],Steadystate],var,{t,0,endTime}], {i,0,100}];
Do[solC1Kma[i]=NDSolve[Join[myODE/.adjustC1Kma[i],D[balance,t],Steadystate],var,{t,0,endTime}], {i,0,100}];

Complex III

Do[solC3Vmax[i]=NDSolve[Join[myODE/.adjustC3Vmax[i],D[balance,t],Steadystate],var,{t,0,endTime}], {i,0,100}];

Complex IV

Do[solC4Vmax[i]=NDSolve[Join[myODE/.adjustC4Vmax[i],D[balance,t],Steadystate],var,{t,0,endTime}], {i,0,100}];

Vmax Variation

J1Vmax= Flatten[Table[((JC1[endTime]/.adjustC1Vmax[i])/.solC1Vmax[i])/((JC1[endTime]/.adjustC1Vmax[0])/.solC1Vmax[0]), {i, 0, 100}]];
Show[ListPlot[J1Vmax, AxesLabel->{"Vmax % inhibited", "Complex I Flux"},Joined->True,PlotRange->All,PlotStyle->Orange,AxesOrigin->{1,0},DisplayFunction->Identity],DisplayFunction->$DisplayFunction]
J3Vmax= Flatten[Table[((JC3[endTime]/.adjustC3Vmax[i])/.solC3Vmax[i])/((JC3[endTime]/.adjustC3Vmax[0])/.solC3Vmax[0]), {i, 0, 100}]];
Show[ListPlot[J3Vmax, AxesLabel->{"Vmax % inhibited", "Complex III Flux"},Joined->True,PlotRange->All,PlotStyle->Orange,AxesOrigin->{1,0},DisplayFunction->Identity],DisplayFunction->$DisplayFunction]
J4Vmax= Flatten[Table[((JC4[endTime]/.adjustC4Vmax[i])/.solC4Vmax[i])/((JC4[endTime]/.adjustC4Vmax[0])/.solC4Vmax[0]), {i, 0, 100}]];
Show[ListPlot[J4Vmax, AxesLabel->{"Vmax % inhibited", "Complex IV Flux"},Joined->True,PlotRange->All,PlotStyle->Orange,AxesOrigin->{1,0},DisplayFunction->Identity],DisplayFunction->$DisplayFunction]

Isolated Flux Parameter Variation

Isolated C1 Flux Parameter Variation

isoC1=NDSolve[Join[{NADH'[t]==-JC1[t]/.adjust,CoQ'[t]==-JC1[t]/.adjust} ,D[{NAD[t]+NADH[t]==300,CoQ[t]+CoQH2[t]== 150},t],{CoQ[0]==CoQss,CoQH2[0]==CoQH2ss,NADH[0]==NADHss,NAD[0]==NADss}], {NADH,NAD,CoQ,CoQH2}, {t, 0, endTime}];
Do[isoC1Vmax[i]=NDSolve[Join[{NADH'[t]==-JC1[t]/.adjustC1Vmax[i],CoQ'[t]==-JC1[t]/.adjustC1Vmax[i]} ,D[{NAD[t]+NADH[t]==300,CoQ[t]+CoQH2[t]== 150},t],{CoQ[0]==CoQss,CoQH2[0]==CoQH2ss,NADH[0]==NADHss,NAD[0]==NADss}], {NADH,NAD,CoQ,CoQH2}, {t, 0, endTime}], {i,0,100}];

v1Vmax= Flatten[Table[((JC1[0]/.adjustC1Vmax[i])/.isoC1Vmax[i])/((JC1[0]/.adjustC1Vmax[0])/.isoC1Vmax[0]), {i, 0, 100}]];

Isolated C3 Flux Parameter Variation

isoC3=NDSolve[Join[{CoQH2'[t]==-JC3[t]/.adjust,cytCox'[t]==-2JC3[t]/.adjust} ,D[{cytCred[t]+cytCox[t]==cytCtot,CoQ[t]+CoQH2[t]== CoQtot},t],{CoQ[0]==CoQss,CoQH2[0]==CoQH2ss,cytCred[0]==cytCredss,cytCox[0]==cytCoxss}], {cytCred,cytCox,CoQ,CoQH2}, {t, 0, endTime}];
Do[isoC3Vmax[i]=NDSolve[Join[{CoQH2'[t]==-JC3[t]/.adjustC3Vmax[i],cytCox'[t]==-2JC3[t]/.adjustC3Vmax[i]} ,D[{cytCred[t]+cytCox[t]==cytCtot,CoQ[t]+CoQH2[t]== CoQtot},t],{CoQ[0]==CoQss,CoQH2[0]==CoQH2ss,cytCred[0]==cytCredss,cytCox[0]==cytCoxss}], {cytCred,cytCox,CoQ,CoQH2}, {t, 0, endTime}], {i,0,100}];

v3Vmax= Flatten[Table[((JC3[0]/.adjustC3Vmax[i])/.isoC3Vmax[i])/((JC3[0]/.adjustC3Vmax[0])/.isoC3Vmax[0]), {i, 0, 100}]];

Isolated C4 Flux Parameter Variation

isoC4=NDSolve[Join[{cytCred'[t]==-2JC4[t]/.adjust,O2'[t]==0} ,D[{cytCred[t]+cytCox[t]==cytCtot},t],{O2[0]==30,cytCred[0]==cytCredss,cytCox[0]==cytCoxss}], {cytCred,cytCox,O2}, {t, 0, endTime}];
Do[isoC4Vmax[i]=NDSolve[Join[{cytCred'[t]==-2JC4[t]/.adjustC4Vmax[i],O2'[t]==0} ,D[{cytCred[t]+cytCox[t]==cytCtot},t],{O2[0]==30,cytCred[0]==cytCredss,cytCox[0]==cytCoxss}], {cytCred,cytCox,O2}, {t, 0, endTime}], {i,0,100}];

v4Vmax= Flatten[Table[((JC4[0]/.adjustC4Vmax[i])/.isoC4Vmax[i])/((JC4[0]/.adjustC4Vmax[0])/.isoC4Vmax[0]), {i, 0, 100}]];

Isolated Flux Parameter Variation Plots

Complex I

Show[ListPlot[v1Vmax, AxesLabel->{"Vmax % inhibited", "Complex I v"},Joined->True,PlotRange->All,PlotStyle->Orange,AxesOrigin->{1,0},DisplayFunction->Identity],DisplayFunction->$DisplayFunction]

Complex III

Show[ListPlot[v3Vmax, AxesLabel->{"Vmax % inhibited", "Complex 3 v"},Joined->True,PlotRange->All,PlotStyle->Orange,AxesOrigin->{1,0},DisplayFunction->Identity],DisplayFunction->$DisplayFunction]

Complex IV

Show[ListPlot[v4Vmax, AxesLabel->{"Vmax % inhibited", "Complex 4 v"},Joined->True,PlotRange->All,PlotStyle->Orange,AxesOrigin->{1,0},DisplayFunction->Identity],DisplayFunction->$DisplayFunction]

Isolated to Global Flux Comparison

Vmax

JointC1Vmax=Show[ShowLegend[ListLinePlot[{v1Vmax*100,J1Vmax*100},Frame->{{True,False},{True,False}},FrameLabel->{Style["%((Subscript[V, max])^f) Decrease",Bold], Style["%Activity",Bold]},FrameStyle->{{AbsoluteThickness[1],White},{AbsoluteThickness[1],White}},PlotRange->{{0,100},{0,100}},LabelStyle->{FontFamily->"Arial", FontSize -> 8},PlotStyle->{{Orange,AbsoluteThickness[1]},{CIColor, AbsoluteThickness[1]}},BaseStyle -> {FontFamily->"Arial", FontSize -> 8, PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}}],{{{Graphics[{Orange,Thick,Line[{{0,0},{1,0}}]}],Style["(Subscript[v, 1])",FontFamily->"Arial",FontSize->8]},
{Graphics[{CIColor,Thick,Line[{{0,0},{1,0}}]}],Style["J",FontFamily->"Arial",FontSize->8]}
},  LegendLabel->None,LegendPosition -> {-0.7,-0.27}, LegendShadow->{.02,-.02},LegendSize->0.3,LegendOrientation->Horizontal}],Graphics[Text[StyleForm["A",FontFamily->"Arial",FontSize->12,FontWeight->"Bold"],{Left,Top},{-1.5,1.25}]],ImageSize -> 242.03]

JointC3Vmax=Show[ListPlot[{v3Vmax,J3Vmax}, AxesLabel->{"Vmax % decrease", "Complex III Flux"},Joined->True,PlotRange->All,PlotStyle->{Orange,Red},AxesOrigin->{1,0},DisplayFunction->Identity],DisplayFunction->$DisplayFunction]

JointC4Vmax=Show[ListPlot[{v3Vmax,J3Vmax}, AxesLabel->{"Vmax % decrease", "Complex IV Flux"},Joined->True,PlotRange->All,PlotStyle->{Orange,Red},AxesOrigin->{1,0},DisplayFunction->Identity],DisplayFunction->$DisplayFunction]

Threshold Comparison

tV1Vmax = Partition[(1 - v1Vmax), 1];
tJ1Vmax = Partition[J1Vmax, 1];
thresholdJ1Vmax = Join[tV1Vmax, tJ1Vmax, 2];

tV3Vmax = Partition[(1 - v3Vmax), 1];
tJ3Vmax = Partition[J3Vmax, 1];
thresholdJ3Vmax = Join[tV3Vmax, tJ3Vmax, 2];

tV4Vmax = Partition[(1 - v4Vmax), 1];
tJ4Vmax = Partition[J4Vmax, 1];
thresholdJ4Vmax = Join[tV4Vmax, tJ4Vmax, 2];

threshold=Show[ShowLegend[ListLinePlot[{thresholdJ1Vmax*100, thresholdJ3Vmax*100, thresholdJ4Vmax*100},Frame->{{True,False},{True,False}},PlotRange->{{0,100},{0,100}},
FrameLabel->{Style["%(Subscript[v, i]) Decrease",FontFamily->"Arial",Bold,FontSize -> 8], Style["%J Activity",Bold,FontSize -> 8]}, FrameStyle->{{AbsoluteThickness[1],White},{AbsoluteThickness[1],White}},LabelStyle->{FontFamily->"Arial", FontSize -> 8},
PlotStyle->{{CIColor,AbsoluteThickness[1]}, {CIIIColor,AbsoluteThickness[1]}, {CIVColor, AbsoluteThickness[1]}},
BaseStyle -> {FontFamily->"Arial", FontSize -> 8, PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}}],{{{Graphics[{CIColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["I",FontFamily->"Arial",Bold,FontSize->8]},
{Graphics[{CIIIColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["III",FontFamily->"Arial",Bold,FontSize->8]},
{Graphics[{CIVColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["IV",FontFamily->"Arial",Bold,FontSize->8]}
}, LegendLabel->Style["(Complex I (Subscript[K, R, D])=0.03)",FontFamily->"Arial",8,PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}],LegendPosition -> {-0.68,-0.28}, LegendShadow->{.02,-.01},LegendLabelSpace->0.8,LegendSize->{0.75,0.4},LegendOrientation->Horizontal}
],Graphics[Text[StyleForm["B",FontFamily->"Arial",FontSize->12,FontWeight->"Bold"],{Left,Top},{-1.5,1.25}]],ImageSize -> 242.03]

threshold2=Show[ShowLegend[ListLinePlot[{thresholdJ1Vmax*100, thresholdJ3Vmax*100, thresholdJ4Vmax*100},Frame->{{True,False},{True,False}},PlotRange->{{0,100},{0,100}},
FrameLabel->{Style["%(Subscript[v, i]) Decrease",FontFamily->"Arial",Bold,FontSize -> 8], Style["%J Activity",Bold,FontSize -> 8]}, FrameStyle->{{AbsoluteThickness[1],White},{AbsoluteThickness[1],White}},LabelStyle->{FontFamily->"Arial", FontSize -> 8},
PlotStyle->{{CMYKColor[0.0392,0.0863,0.949,0],AbsoluteThickness[1]}, {CMYKColor[0.1922,0.8392,0.6039,.0471],AbsoluteThickness[1]}, {CMYKColor[0.7804,0.1843,1,0.0392], AbsoluteThickness[1]}},
BaseStyle -> {FontFamily->"Arial", FontSize -> 8, PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}}],{{{Graphics[{CMYKColor[0.0392,0.0863,0.949,0],AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["I",FontFamily->"Arial",Bold,FontSize->8]},
{Graphics[{CMYKColor[0.1922,0.8392,0.6039,.0471],AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["III",FontFamily->"Arial",Bold,FontSize->8]},
{Graphics[{CMYKColor[0.7804,0.1843,1,0.0392],AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["IV",FontFamily->"Arial",Bold,FontSize->8]}
}, LegendLabel->Style["(Complex I (Subscript[K, R, D])=1.0)",FontFamily->"Arial",8,PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}],LegendPosition -> {-0.68,-0.28}, LegendShadow->{.02,-.01},LegendLabelSpace->0.8,LegendSize->{0.75,0.4},LegendOrientation->Horizontal}
],Graphics[Text[StyleForm["B",FontFamily->"Arial",FontSize->12,FontWeight->"Bold"],{Left,Top},{-1.5,1.25}]],ImageSize -> 242.03]

threshold3=Show[ShowLegend[ListLinePlot[{thresholdJ1Vmax*100, thresholdJ3Vmax*100, thresholdJ4Vmax*100},Frame->{{True,False},{True,False}},PlotRange->{{0,100},{0,100}},
FrameLabel->{Style["%(Subscript[v, i]) Decrease",FontFamily->"Arial",Bold,FontSize -> 8], Style["%J Activity",Bold,FontSize -> 8]}, FrameStyle->{{AbsoluteThickness[1],White},{AbsoluteThickness[1],White}},LabelStyle->{FontFamily->"Arial", FontSize -> 8},
PlotStyle->{{CIColor,AbsoluteThickness[1]}, {CIIIColor,AbsoluteThickness[1]}, {CIVColor, AbsoluteThickness[1]}},
BaseStyle -> {FontFamily->"Arial", FontSize -> 8, PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}}],{{{Graphics[{CIColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["I",FontFamily->"Arial",Bold,FontSize->8]},
{Graphics[{CIIIColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["III",FontFamily->"Arial",Bold,FontSize->8]},
{Graphics[{CIVColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["IV",FontFamily->"Arial",Bold,FontSize->8]}
}, LegendLabel->Style["(Complex I (Subscript[K, S, D])=100)",FontFamily->"Arial",8,PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}],LegendPosition -> {-0.68,-0.28}, LegendShadow->{.02,-.01},LegendLabelSpace->0.8,LegendSize->{0.75,0.4},LegendOrientation->Horizontal}
],Graphics[Text[StyleForm["B",FontFamily->"Arial",FontSize->12,FontWeight->"Bold"],{Left,Top},{-1.5,1.25}]],ImageSize -> 242.03]

threshold4=Show[ShowLegend[ListLinePlot[{thresholdJ1Vmax*100, thresholdJ3Vmax*100, thresholdJ4Vmax*100},Frame->{{True,False},{True,False}},PlotRange->{{0,100},{0,100}},
FrameLabel->{Style["%(Subscript[v, i]) Decrease",FontFamily->"Arial",Bold,FontSize -> 8], Style["%J Activity",Bold,FontSize -> 8]}, FrameStyle->{{AbsoluteThickness[1],White},{AbsoluteThickness[1],White}},LabelStyle->{FontFamily->"Arial", FontSize -> 8},
PlotStyle->{{CIColor,AbsoluteThickness[1]}, {CIIIColor,AbsoluteThickness[1]}, {CIVColor, AbsoluteThickness[1]}},
BaseStyle -> {FontFamily->"Arial", FontSize -> 8, PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}}],{{{Graphics[{CIColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["I",FontFamily->"Arial",Bold,FontSize->8]},
{Graphics[{CIIIColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["III",FontFamily->"Arial",Bold,FontSize->8]},
{Graphics[{CIVColor,AbsoluteThickness[1.5],Line[{{0,0},{1,0}}]}],Style["IV",FontFamily->"Arial",Bold,FontSize->8]}
}, LegendLabel->Style["(Complex I γ=0.01)",FontFamily->"Arial",8,PrivateFontOptions->{"OperatorSubstitution"->False,"WindowsUseTrueTypeNames"->True}],LegendPosition -> {-0.68,-0.28}, LegendShadow->{.02,-.01},LegendLabelSpace->0.8,LegendSize->{0.75,0.4},LegendOrientation->Horizontal}
],Graphics[Text[StyleForm["B",FontFamily->"Arial",FontSize->12,FontWeight->"Bold"],{Left,Top},{-1.5,1.25}]],ImageSize -> 242.03]